StockFetcher Forums · Filter Exchange · BIGG Brexit Meeting next week...how is everyone playing it?<< 1 2 3 4 5 ... 7 >>Post Follow-up
pthomas215
451 posts
msg #129167
Ignore pthomas215
6/15/2016 10:29:16 PM

It appears that TVIX will respond to volatility due to the big brexit meeting next week. Any thoughts on how to play England possibly leaving the current European union?

johnpaulca
10,299 posts
msg #129170
Ignore johnpaulca
modified
6/15/2016 11:39:18 PM

Brexit....This is the kind of sentiment will leads to extreme risk-aversion. Global capital might soon be pouring into the US, pushing bond prices up and interest rates down.....how do you say...negative interest rate.

pthomas215
451 posts
msg #129171
Ignore pthomas215
6/16/2016 12:20:23 AM

I agree. I think it's going to be bigger than people think. by next week there may be a rush to bonds and cash due to instability. I would think TVIX will pull back a bit until next Wednesday, and then explode.

graftonian
220 posts
msg #129174
Ignore graftonian
6/16/2016 7:38:27 AM

I agree, the overall effect will be negative for equities.

Kevin_in_GA
3,976 posts
msg #129194
Ignore Kevin_in_GA
6/16/2016 5:49:07 PM

Volatility ETF pair trades

pthomas215
451 posts
msg #129200
Ignore pthomas215
6/17/2016 1:07:53 AM

Kevin, do you mind explaining your strategy around pair trades? what do you look for, when do you go long/short?

Kevin_in_GA
3,976 posts
msg #129201
Ignore Kevin_in_GA
6/17/2016 7:41:06 AM

You guys always want to play directional on these events, leaving yourself open to guessing wrong and getting screwed. I prefer to use mean reversion on pair trades which, while perhaps not giving the same thrill of a big win will minimize the risk of loss.

Example:

Fetcher[
SYMLIST(VIXM,VXZ)

/*CALCULATE THE PAIR RATIO*/
SET{LEFT, IND(VIXM,CLOSE)}
SET{RIGHT, IND(VXZ,CLOSE)}
SET{RATIO, LEFT / RIGHT}
SET{PAIRSPREAD, LEFT - RIGHT}

/*DETERMINE THE 14 DAY MOVING AVERAGE FOR THE RATIO*/
SET{RATIOMA14, CMA(RATIO,14)}
SET{SPREADMA14, CMA(PAIRSPREAD,14)}

/*DETERMINE THE PERCENT ABOVE/BELOW THE MA(14) FOR THE RATIO*/
SET{RATIOPCT1, RATIO / RATIOMA14}
SET{RATIOPCT2, RATIOPCT1 - 1}
SET{RATIOPCT, RATIOPCT2 * 100}

/*DETERMINE THE 14 DAY ZSCORE FOR THE RATIO*/
SET{RATIOSTD14, CSTDDEV(RATIO,14)}
SET{RATIO2STD, 2 * RATIOSTD14}
SET{RATIOUPPERBB, RATIOMA14 + RATIO2STD}
SET{RATIOLOWERBB, RATIOMA14 - RATIO2STD}
SET{RATIODIFF14, RATIO - RATIOMA14}
SET{RATIOZSCORE, RATIODIFF14 / RATIOSTD14}

SET{SPREADSTD14, CSTDDEV(PAIRSPREAD,14)}
SET{SPREADDIFF14, PAIRSPREAD - SPREADMA14}
SET{SPREADZSCORE, SPREADDIFF14 / SPREADSTD14}

/*DETERMINE DIRECTION OF PAIR TRADE AND THE NUMBER OF SHARES TO BE BOUGHT OR SOLD*/
SET{BELOWLBB, COUNT(RATIOZSCORE BELOW -2,1)}
SET{ABOVEUBB, COUNT(RATIOZSCORE ABOVE 2,1)}

SET{LEFTSHARES1, 10000 / LEFT}
SET{LEFTSHARES, ROUND(LEFTSHARES1, 0)}
SET{LEFTLONG, BELOWLBB * LEFTSHARES}
SET{LEFTSHORT, ABOVEUBB * LEFTSHARES}

SET{RIGHTSHARES1, 10000 / RIGHT}
SET{RIGHTSHARES, ROUND(RIGHTSHARES1, 0)}
SET{RIGHTLONG, ABOVEUBB * RIGHTSHARES}
SET{RIGHTSHORT, BELOWLBB * RIGHTSHARES}

/*FORMAT FILTER COLUMN OUTPUT*/
ADD COLUMN AVERAGE VOLUME(50) {AVERAGE VOLUME}
ADD COLUMN SEPARATOR
ADD COLUMN RATIOZSCORE {RATIO Z-SCORE}
ADD COLUMN RATIOPCT {PERCENT AWAY FROM MEAN}
ADD COLUMN SEPARATOR
ADD COLUMN SPREADZSCORE {SPREAD Z-SCORE}
ADD COLUMN SPREADDIFF14 {SPREAD DIFFERENCE}
ADD COLUMN SEPARATOR
ADD COLUMN LEFTLONG {VIXM - SHARES LONG}
ADD COLUMN RIGHTSHORT {VXZ - SHARES SHORT}

ADD COLUMN SEPARATOR
ADD COLUMN LEFTSHORT {VIXM - SHARES SHORT}
ADD COLUMN RIGHTLONG {VXZ - SHARES LONG}
ADD COLUMN SEPARATOR

/*DRAW RATIO PLOT AND ZSCORE*/
DRAW RATIO ON PLOT RATIOMA14
DRAW RATIOUPPERBB ON PLOT RATIOMA14
DRAW RATIOLOWERBB ON PLOT RATIOMA14

PLOTTYPE{RATIOZSCORE, ZEROBAR}
DRAW RATIOZSCORE LINE AT 2
DRAW RATIOZSCORE LINE AT -2
DRAW RATIOZSCORE LINE AT 0

PLOTTYPE{SPREADZSCORE, ZEROBAR}
DRAW SPREADZSCORE LINE AT 2
DRAW SPREADZSCORE LINE AT -2
DRAW SPREADZSCORE LINE AT 0

CHART-TIME IS 6 MONTHS
]



This simply plays VIXM versus VXZ - if the ratio of these two ETFs goes outside of the BB(14,2) in either direction you bet long/short on a mean reversion.

How has this particular pair strategy done over the past five years?

https://www.pairtradinglab.com/backtests/V2Pg8zHfkxL8y57c

It returned almost 10% per year (beating the return of the S&P over the same time frame) but had only a 2.2% max drawdown and was profitable 100% of the time - 101 pair trades entered, 101 profitable.



johnpaulca
10,299 posts
msg #129205
Ignore johnpaulca
6/17/2016 9:04:59 AM

Kevin, this is fantastic, could make my pairs trading a lot easier....thank you!!

pthomas215
451 posts
msg #129207
Ignore pthomas215
6/17/2016 9:42:35 AM

Thank you Kevin. not trying to play directional...just wanted to understand what you were saying. some of this stuff is new to me.

ferndave
23 posts
msg #129256
Ignore ferndave
6/20/2016 3:47:37 PM

Kevin, for those who don't have an account that allows shorting, can this filter be used with buying XIV instead? Use it like an indicator?

StockFetcher Forums · Filter Exchange · BIGG Brexit Meeting next week...how is everyone playing it?<< 1 2 3 4 5 ... 7 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus