StockFetcher Forums · Filter Exchange · NYSE New Highs / New Lows<< >>Post Follow-up
tomm1111
202 posts
msg #85851
- Ignore tomm1111
modified		 1/9/2010 1:05:44 AM

Here is a filter based on NYSE # of new highs and new lows. It is presented 3 ways.

1. NHNL Oscillator (+/- actual NH-NL, 0 center)
2. NHNL Ratio (-100 to 100, 0 center)
3. NHNL 10/30 ema crossover

This has been an impressive bull run since march '09. The High/Low oscillator is solidly positive.


Fetcher[
/* NYSE New Highs/New Lows */
symlist(spy)

set{newh,ind(^hign,close)}
set{newl,ind(^lown,close)}

set{HL_osc,newh-newl}
set{denom,newh+newl}
set{calc,HL_osc/denom}
set{HL_ratio,100*calc}
set{ratio_ema,cema(HL_ratio,9)}

draw HL_osc
draw HL_osc line at 0
draw HL_ratio
draw ratio_ema on plot HL_ratio
draw HL_ratio line at 0

set{HL_10ema,cema(HL_osc,10)}
set{HL_30ema,cema(HL_osc,30)}

draw HL_10ema
draw HL_30ema on plot HL_10ema
and chart-time is 1 year
]
mesayah
658 posts
msg #85856
- Ignore mesayah		 1/9/2010 5:25:20 AM

i like this alot...
Kevin_in_GA
4,599 posts
msg #85862
- Ignore Kevin_in_GA
modified		 1/9/2010 8:40:07 AM

Nice - somebody has been looking at the index list!

If you don't mind, I have incorporated this with the filter I posted a few days ago that tracks the A/D stocks and Up/Down Volume for the NYSE. Now it is sort of a "Holy Trinity" for overall market trend.

Fetcher[

/*"HOLY TRINITY" MARKET INDICATOR BASED ON THE NYSE MARKET DATA*/

/*SET RATIO OF ADVANCING AND DECLINING STOCKS ON NYSE AS A VARIABLE AND CREATE A MOVING AVERAGE OSCILLATOR*/
set{var1,ind(^adra,close)}
set{count_oscillator, CEMA(var1,10)}

/*SET NYSE ADVANCING VOLUME / DECLINING VOLUME RATIO AS SECOND VARIABLE AND CREATE A SIMILAR OSCILLATOR*/
set{var3,ind(^nvlu,close)}
set{var4,ind(^nvld,close)}

set{advancing_volume, CEMA(var3,10)}
set{declining_volume, CEMA(var4,10)}
set{volume_oscillator, advancing_volume / declining_volume}

/*SET NEW HIGHS - NEW LOWS AS THIRD INDICATOR*/
set{newh,ind(^hign,close)}
set{newl,ind(^lown,close)}
set{HL_osc,newh-newl}

draw count_oscillator line at 1
draw volume_oscillator line at 1
draw HL_osc line at 0

add column count_oscillator {count oscillator}
add column volume_oscillator {volume oscillator}
add column HL_osc {new highs - new lows}
symlist(spy)
chart-time is 6 months

]



Obviously, one would go long when these oscillators are above 1.0, and sell or go short when they dip below. Note also that new highs - new lows tends to give the longest term picture, but may also be the slowest to respond to a strong change in market trend.

Thanks!




tomm1111
202 posts
msg #85867
- Ignore tomm1111		 1/9/2010 11:11:17 AM

Thx guys.

Kevin, That is a good spot for it. As you say, it provides a good long term picture. Those 3 work together well.



tomm1111
202 posts
msg #90788
- Ignore tomm1111		 4/4/2010 8:01:39 PM

With the new highs - new lows are on the decline, I would expect the market to follow suit at some point. The new high - new low 10ma crossed below the 30ma. Those signals have been fairly reliable recently on catching direction of the trend. I would be surprised if the market moves sideways for another week.

Fetcher[
/* NYSE New Highs/New Lows */
symlist(spy)

set{newh,ind(^hign,close)}
set{newl,ind(^lown,close)}

set{HL_osc,newh-newl}
set{denom,newh+newl}
set{calc,HL_osc/denom}
set{HL_ratio,100*calc}
set{ratio_ema,cema(HL_ratio,9)}

set{HL_10ema,cema(HL_osc,10)}
set{HL_30ema,cema(HL_osc,30)}

set{long,count(HL_10ema crossed above HL_30ema,1)}
set{short,count(HL_30ema crossed above HL_10ema,1)}
draw long
draw short on plot long
draw HL_10ema
draw HL_30ema on plot HL_10ema

draw HL_osc
draw HL_osc line at 0
draw HL_ratio
draw ratio_ema on plot HL_ratio
draw HL_ratio line at 0

and chart-time is 6 months
]
tomm1111
202 posts
msg #95071
- Ignore tomm1111
modified		 7/24/2010 11:31:26 PM

I've added bollinger bands to the daily and weekly HL ratio. Signals occur when the HL_ratio line crosses the upper and lower bands.

data used: # of stocks making 52 week highs/lows


Fetcher[
/* NYSE New Highs/New Lows */
symlist(spy)

set{newh,ind(^hign,close)}
set{newl,ind(^lown,close)}
set{newhwk,ind(^hign,weekly close)}
set{newlwk,ind(^lown,weekly close)}

/* Daily HL oscillator calcs */
set{HL_osc,newh-newl}
set{denom,newh+newl}
set{calc,HL_osc/denom}
set{HL_ratio,100*calc}
set{ratio_ema,cema(HL_ratio,4)}

/* Weekly HL oscillator calcs */
set{HL_oscwk,newhwk-newlwk}
set{denomwk,newhwk+newlwk}
set{calcwk,HL_oscwk/denomwk}
set{HL_ratiowk,100*calcwk}
set{ratio_ema_wk,cema(HL_ratiowk,9)}

/* Daily high low */
set{HL_10ema,cema(HL_osc,10)}
set{HL_30ema,cema(HL_osc,30)}
set{long_x,count(HL_10ema crossed above HL_30ema,1)}
set{short_x,count(HL_30ema crossed above HL_10ema,1)}
draw long_x
draw short_x on plot long_x

/* Daily high low bollinger band */
set{bbsd,3.3 * cstddev(ratio_ema,20)}
set{bbup,CMA(ratio_ema,20) + bbsd}
set{bbdn,CMA(ratio_ema,20) - bbsd}
set{long_bb,count(ratio_ema crossed above bbdn,1)}
set{short_bb,count(ratio_ema crossed below bbup,1)}
draw long_bb
draw short_bb on plot long_bb

/* Weekly high low bollinger band */
set{bbsdwk,1.3 * cstddev(ratio_ema_wk,20)}
set{bbupwk,CMA(ratio_ema_wk,20) + bbsdwk}
set{bbdnwk,CMA(ratio_ema_wk,20) - bbsdwk}
set{long_bb_wk,count(ratio_ema_wk crossed above bbdnwk,1)}
set{short_bb_wk,count(ratio_ema_wk crossed below bbupwk,1)}
draw long_bb_wk
draw short_bb_wk on plot long_bb_wk
draw HL_10ema
draw HL_30ema on plot HL_10ema

draw ratio_ema
draw bbdn on plot ratio_ema
draw bbup on plot ratio_ema
draw CMA(ratio_ema,20) on plot ratio_ema

draw ratio_ema_wk
draw bbdnwk on plot ratio_ema_wk
draw bbupwk on plot ratio_ema_wk
draw CMA(ratio_ema_wk,20) on plot ratio_ema_wk

draw HL_osc
draw HL_osc line at 0
draw HL_ratio
draw ratio_ema on plot HL_ratio
draw HL_ratio line at 0

and chart-time is 6 months
draw parabolic SAR
draw ema(20)
draw ema(50)
]
tomm1111
202 posts
msg #96247
- Ignore tomm1111		 9/13/2010 10:51:28 PM

I've simplified the filter to the following. Decent signals over the last couple years. No sell signal yet but close.

Fetcher[
/* NYSE New Highs/New Lows */
symlist(spy)

set{newhwk,ind(^hign,weekly close)}
set{newlwk,ind(^lown,weekly close)}

/* Weekly HL oscillator calcs */
set{HL_oscwk,newhwk-newlwk}
set{denomwk,newhwk+newlwk}
set{calcwk,HL_oscwk/denomwk}
set{HL_ratiowk,100*calcwk}
set{ratio_ema_wk,cema(HL_ratiowk,9)}

/* Weekly high low bollinger band */
set{bbsdwk,1.3 * cstddev(ratio_ema_wk,20)}
set{bbupwk,CMA(ratio_ema_wk,20) + bbsdwk}
set{bbdnwk,CMA(ratio_ema_wk,20) - bbsdwk}
set{long_bb_wk,count(ratio_ema_wk crossed above bbdnwk,1)}
set{short_bb_wk,count(ratio_ema_wk crossed below bbupwk,1)}
draw long_bb_wk
draw short_bb_wk on plot long_bb_wk

draw ratio_ema_wk
draw bbdnwk on plot ratio_ema_wk
draw bbupwk on plot ratio_ema_wk
draw CMA(ratio_ema_wk,20) on plot ratio_ema_wk

and chart-time is 6 months
draw parabolic SAR
draw ema(20)
draw ema(50)
]
StockFetcher Forums · Filter Exchange · NYSE New Highs / New Lows<< >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.