StockFetcher Forums · Filter Exchange · Three White Soldiers<< 1 2 >>Post Follow-up
Underworlds
30 posts
msg #90944
Ignore Underworlds
4/8/2010 11:39:53 PM

I've been trying to come up with a filter that detects Bullish Three White Soldiers where the minimum length of the body is relative to the open. Everything that I've found about the Three White Soldiers suggests that the bodies of the candlesticks should be "long", but I have not been able to find a definitive definition of what "long" should be.

What I have decided to assume is that a change from open to close of 4% or more will be considered a "long" candlestick. Please check out my filter below and make any suggestions that you can think of to help me improve upon it.

Note also that I wanted to place the Three White Soldiers at the foot of a definite downward trend. To do that, I simply looked for the pattern where the MACD Fast Line was below 0.

Fetcher[/* Three White Soldiers */

set{wht_long,Open 2 days ago * 0.04}

set{body2,Open 2 days ago + wht_long}
Close 2 days ago is greater than Open 2 days ago
High 2 days ago is greater than Close 2 days ago
Open 2 days ago is greater than Low 2 days ago
Close 2 days ago is greater than body2

set{body1,Open 1 day ago + wht_long}
Close 1 day ago is greater than Open 1 day ago
High 1 day ago is greater than Close 1 day ago
Open 1 day ago is greater than Low 1 day ago
Close 1 day ago is greater than body1

set{body,Open + wht_long}
Close is greater than Open
High is greater than Close
Open is greater than Low
Close is greater than body

Open is greater than Open 1 day ago
Open is less than Close 1 day ago
Open 1 day ago is greater than Open 2 days ago
Open 1 day ago is less than Close 2 days ago
Close is greater than Close 1 day ago
Close 1 day ago is greater than Close 2 days ago

MACD Fast Line(12,26) is less than 0
Market is not OTCBB

draw MACD Fast Line(12,26)
draw MACD Slow Line(12,26) on plot MACD Fast Line(12,26)
draw RSI(14)
draw Momentum(10)
draw CEMA(Momentum(10),5) on plot Momentum(10)

do not draw body
do not draw body1
do not draw body2
]



Underworlds
30 posts
msg #90948
Ignore Underworlds
4/9/2010 2:45:20 AM

The following approach to the Three White Soldiers takes into consideration the requirements outlined at streetauthority.com as follows...

The pattern appears (a) after an extended decline and (b) a period of subsequent consolidation. The pattern is valid as long as (c) the candle of day 2 opens in the upper half of day one's range. On day 2 the stock should (d) close near its high, leaving a very small or non-existent upper shadow. (e) The same pattern is then repeated on day 3.

Additional signals to look for, according to that referenced site, is that (f) the ADX(14) should begin to trend upward from a very low level (less than 25) and (g) +DI should cross above -DI during the formation of the Three White Soldiers pattern.

Fetcher[/* Three White Soldiers - ver. 1.1 */

set{wht_long,Open 2 days ago * 0.015}

Price is greater than 0.5
Market is not OTCBB

set{body2, Open 2 days ago + wht_long}
set{height2, Close 2 days ago - Open 2 days ago}
set{ttl_height2, height2 / 0.8}
set{shadow2, ttl_height2 - height2}
set{high_shadow2_max, shadow2 / 2}
set{high_shadow2, Close 2 days ago + high_shadow2_max}

Close 2 days ago is greater than body2
High 2 days ago is less than high_shadow2
High 2 days ago is greater than Close 2 days ago
Open 2 days ago is greater than Low 2 days ago

set{body1, Open 1 day ago + wht_long}
set{height1, Close 1 day ago - Open 1 day ago}
set{ttl_height1, height1 / 0.8}
set{shadow1, ttl_height1 - height1}
set{high_shadow1_max, shadow1 / 2}
set{high_shadow1, Close 1 days ago + high_shadow1_max}

Close 1 day ago is greater than body1
High 1 day ago is less than high_shadow1
High 1 day ago is greater than Close 1 day ago
Open 1 day ago is greater than Low 1 day ago

set{body, Open + wht_long}
set{height, Close - Open}
set{ttl_height, height / 0.8}
set{shadow, ttl_height - height}
set{high_shadow_max, shadow / 2}
set{high_shadow, Close + high_shadow_max}

Close is greater than body
High is less than high_shadow
High is greater than Close
Open is greater than Low

set{body2_mid, height2 / 2}
set{body1_mid, height1 / 2}

Open 1 day ago is greater than body2_mid
Open 1 day ago is less than Close 2 days ago
Close 1 day ago is greater than Close 2 days ago
Open is greater than body1_mid
Open is less than Close 1 day ago
Close is greater than Close 1 day ago

MACD Fast Line(12,26) 5 days ago is less than 0
MACD Fast Line(12,26) 5 days ago is less than MACD Slow Line(12,26) 5 days ago

ADX(14) 1 day ago is less than 30
ADX(14) is greater than ADX(14) 1 day ago
+DI(14) crossed above the -DI(14) within the last 4 days

/* Do not draw variables */
do not draw body2
do not draw high_shadow2
do not draw body1
do not draw high_shadow1
do not draw body
do not draw high_shadow
do not draw body2_mid
do not draw body1_mid

/* Draw commonly used indicators */
draw MACD Fast Line(12,26)
draw MACD Slow Line(12,26) on plot MACD Fast Line(12,26)
draw RSI(14)
draw RSI(7) on plot RSI(14)
draw RSI(21) on plot RSI(14)
draw Momentum(10)
draw CEMA(Momentum(10),5) on plot Momentum(10)
]





chetron
2,817 posts
msg #90953
Ignore chetron
modified
4/9/2010 6:51:23 AM

MAYBE...
thanx for the heads up, all better now....


Fetcher[
/* Three White Soldiers - CHETRON */

SET{VMAX,MAX(OPEN,CLOSE)}
SET{VMIN,MIN(OPEN,CLOSE)}
SET{VAR2,VMAX - VMIN}
SET{VAR3,CMA(VAR2,3)}
SET{VLB,COUNT(VAR2 ABOVE VAR3,3)}
SET{VAR1,COUNT(CLOSE ABOVE OPEN,3)}
SET{VTWS,VAR1 + VLB}


VTWS ABOVE 5.5
Price is greater than 0.5
Market is not OTCBB



/* Draw commonly used indicators */
draw MACD Fast Line(12,26)
draw MACD Slow Line(12,26) on plot MACD Fast Line(12,26)
draw RSI(14)
draw RSI(7) on plot RSI(14)
draw RSI(21) on plot RSI(14)
draw Momentum(10)
draw CEMA(Momentum(10),5) on plot Momentum(10)

]





Underworlds
30 posts
msg #90988
Ignore Underworlds
4/9/2010 4:41:16 PM

CHETRON - I tried your filter and received the following message: "Your StockFetcher filter exceeds filter performance restrictions"

Mactheriverrat
1,328 posts
msg #91003
Ignore Mactheriverrat
4/10/2010 12:58:36 AM

worked on mine- I have the basic plan

Underworlds
30 posts
msg #91010
Ignore Underworlds
4/10/2010 10:34:49 AM

Odd. I just tried again this morning and it worked this time. Must have been a glitch. Thanx.

Underworlds
30 posts
msg #91011
Ignore Underworlds
4/10/2010 10:52:36 AM

chetron - Nice filter, but it does not conform to the rules that I am finding everywhere for the Three White Soldiers pattern...

a) Most of the results returned were in an uptrend (this is easy enough to fix).

b) The open of day 2 is supposed to occur within the top half of the real body for day 1.

c) The open of day 3 is supposed to occur within the top half of the real boody for day 2.

d) Candlesticks on day 2 and day 3 are supposed to have very small or non-existent upper shadows.

I will try to build upon your example and see what I can come up with. Thanx for the filter.

chetron
2,817 posts
msg #91013
Ignore chetron
4/10/2010 11:22:37 AM

THE MAIN POINT OF THE FILTER WAS TO GIVE YOU A LONG BODY, I LOOK FORWARD TO SEE YOUR IMPROVEMENTS.
THANX


Underworlds
30 posts
msg #91019
Ignore Underworlds
4/10/2010 12:46:26 PM

I see. It most definitely does get me the long body that I was looking for. Great work there!!!

Underworlds
30 posts
msg #91022
Ignore Underworlds
4/10/2010 1:08:25 PM

Here's the solution that I came up with to the placement of the candlesticks, using chetron's method for finding long candlesticks. This solution does not, however, search for the pattern in a downtrend or take into consideration the length of the shadows...

Fetcher[
/* Three White Soldiers - CHETRON/Underworlds */

SET{VMAX,MAX(OPEN,CLOSE)}
SET{VMIN,MIN(OPEN,CLOSE)}
SET{VAR2,VMAX - VMIN}
SET{VAR3,CMA(VAR2,3)}
SET{VLB,COUNT(VAR2 ABOVE VAR3,3)}
SET{VAR1,COUNT(CLOSE ABOVE OPEN,3)}
SET{VTWS,VAR1 + VLB}

VTWS ABOVE 5.5
Price is greater than 0.5
Market is not OTCBB

/* Position Candlesticks */
set{day1_height, close 2 days ago - open 2 days ago}
set{day1_mid, day1_height / 2}
set{day2_min, close 2 days ago - day1_mid}

set{day2_height, close 1 day ago - open 1 day ago}
set{day2_mid, day2_height / 2}
set{day3_min, close 1 day ago - day2_mid}

Close 1 day ago is greater than Close 2 days ago
Close is greater than Close 1 day ago
Open 1 day ago is less than Close 2 days ago
Open 1 day ago is greater than day2_min
Open is less than Close 1 day ago
Open is greater than day3_min
]



StockFetcher Forums · Filter Exchange · Three White Soldiers<< 1 2 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus