StockFetcher Forums · Filter Exchange · Total Score<< >>Post Follow-up
15minoffame
121 posts
msg #104593
Ignore 15minoffame
1/22/2012 10:28:51 PM

I think sometimes we as traders make it more difficult than it should be. For some reason, we're constantly on the look out for that holy grail filter. Many traders, including myself have tried to time the bottom. Many times, that was futile for me. A stock is weak for a reason.

I then thought about fantasy football & baseball. If any of you has ever participated, I'm 100% sure that you picked the BEST, not the worst players still available. Then why do we do the opposite when it comes to picking stocks? That age old saying, "The trend is your friend" is so true! This thought then led me to the NFL quarterback rankings. The rankings are based on categories that a top tier quarterback should have no problem excelling in.

With that in mind, I created my own stocks rankings based on categories that are important to me. Just like the QB rankings, top trending stocks should have no problem excelling in these categories either.

Fetcher[

/*Total Score Rankings*/

optionable
price above 1
average volume(66) above 500000

set{total1, count(close above ema(5), 22) + count(ema(5) above ema(20), 22)}
set{total2, total1 + count(close > close 1 day ago, 22)}
set{total3, total2 + count(close above ma(200), 22)}
set{total4, total3 + count(relative strength(^spx, 22) above 1.09, 22)}
set{totalscore, total4 + count(rsi(14) above 60, 22)}

set{ts_a,totalscore}
set{ts_b,totalscore 5 days ago}
set{a1, ts_a - ts_b}
set{r1, a1 / ts_b}
set{tsdiff, r1 * 100}

set{wclop, weekly close - weekly open}
set{Long_Profit, wclop/ weekly open}
set{wkProfitPct, 100 * Long_Profit}

set{b1, volume - average volume(66)}
set{s1, b1 / average volume(66)}
set{abvavgvol66, s1 *100}

set{c1, slow stochastics fast %k(14,3) 4 week high-slow stochastics fast %k(14,3)}
set{t1, c1/slow stochastics fast %k(14,3)}
set{pctfromhigh, t1*100}

set{d1, rsi(14) 4 week high-rsi(14)}
set{u1, d1/rsi(14)}
set{fromhigh, u1*100}

add column wkProfitPct
add column abvavgvol66{abv vol 66}
add column average day range(10)
add column separator

add column relative strength(^spx,10){rs/10}
add column relative strength(^spx,22){rs/22}
add column separator

add column slow stochastic(14,3) fast %k{stochs(14)}
add column slow stochastics fast %k(14,3) 4 week high{4 wk h}
add column pctfromhigh{from h}
add column separator

add column rsi(14)
add column rsi(14) 4 week high{4 wk h}
add column fromhigh{from h}
add column separator

add column count(close > close 1 day ago, 10){up/10}
add column count(close > close 1 day ago, 22){up/22}
add column separator

add column totalscore 5 days ago{ts 5 dys ago}
add column totalscore
add column tsdiff
add column totalscore 4 week high{4 wk h}
add column count(totalscore above 100, 22){abv 100}
add column separator

totalscore above 99
sort column 24 descending

]



The great thing about this filter is that you can customize categories that are important to you. Here I sorted by Total Score. I also like to sort Total Score difference, too.

I use Total Score in all of my filters. I especially like to see the Total Score difference on filters where the stock has moved above an important moving average, trend line and stocks that's below 200 MA. Take SHLD for example. It had the highest Total Score difference of 133% for optionable stocks under 200 MA. This suggests that the trend is becoming stronger and worth watching!

Of course, for you permabears out there, you can also use Total Score to see trends that are weakening.

Caveat: This filter is based on a 22-day rolling period or roughly a month. A stock can get hammered (like Google), and still have its Total Score high. Its Total Score won't start dropping dramatically until it has a few down days. In other words, you'll still need to do your due diligence!

StockFetcher Forums · Filter Exchange · Total Score<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus