StockFetcher Forums · Filter Exchange · What’s A Dummy Spot?<< 1 2 3 >>Post Follow-up
TheRumpledOne
6,359 posts
msg #57620
Ignore TheRumpledOne
12/5/2007 2:54:16 PM

FOUND THIS ON THE WEB TODAY...

http://dummyspots.com/?page_id=119

What’s A Dummy Spot? (24 Jan 2006)
24 January 2006

My Definition of a Dummy Spot:

A bar or candle having certain characteristics which make it an obvious low-risk entry point into a trade (”so obvious that a dummy could spot it” or “a spot where even a dummy could make money”).

The classic dummy spot is a narrow-range, low-volume inside bar whose break allows you to enter in the direction of the prevailing trend. Sound confusing? It’s actually very simple. See below.

Here’s a beautiful example from just yesterday. One that I completely missed out on, by the way. ;-)
GM chart

*

The overall market was rising.
*

GM had gapped up on the open by 15 cents (gaps are good, they attract attention), and had wandered sideways/down on fizzling volume.
*

The range on the 10:20 EST “inside bar” was from a low of 20.27 to a high of 20.32, just 5 cents.
*

The 10:30 inside bar had a range of 20.24 to 20.31, a lower high, so no trade quite yet.
*

Then the 10:40 bar broke the high of the 10:30 dummy spot , triggering a trade. Entry would have been just above the high of the 10:30 bar at 20.32, with a stop at the low of the same bar, or 20.24.
*

This entry provides a total potential loss of 8 cents. On a 1000-share trade, that would be a total risk of only $80.

The chart tells the rest of the story. With decent money management, you could have gotten a minimum of $21 out of the stock in just a few hours, and potentially much more. Even if you sold at $21 at 1pm, you’d have made $680 from an $80 risk in under 3 hours. Or, if you’re a Big Fish with a larger account, that would be $6800 on an $800 risk in 3 hrs. Not a bad return.

The narrow-range bar provides a natural point for setting a tight stop, and entering in the direction of the trend places you on the side of probability. The ideal trade setup. From there, your position sizing and money management rules take over.
More About Dummy Spots

*

Dummy Spots occur in all time frames, from one-minute bars to daily or even weekly bars. Most traders tend to use 5-minute to 60-minute bars, as those show the best daytrade setups. The 5-min bars can give more false signals, and not much time for evaluation; you often have to trade within a matter of seconds. I’ll occasionally use the 5’s, but only in very specific situations. I usualy stick to 10, 15 and 30-minute bars. They give fewer false signals, and are much easier on the nerves. Every evening I look for possible swing-trade setups using daily bars.
*

Dummy Spots occur many times every day. The difficulty in catching them is not unlike hunting- you have to be at the right place at the right time, know exactly what you’re watching for, and be ready to pull the trigger when the time comes.

So there you have it- “Dummy Spots” is just a name for a specific kind of trading setup. That’s why I chose it for a domain name, but since I’ve had the site up, I’ve heard many other interpretations: “the spot for dummies,” “trades that a dummy (me) spotted,” alternative to “stock spots,” etc.



fokane
74 posts
msg #57632
Ignore fokane
12/5/2007 4:37:19 PM

This is also a must-read:
http://dummyspots.com/2006/11/it-aint-so-easy/

:-)

TheRumpledOne
6,359 posts
msg #57647
Ignore TheRumpledOne
modified
12/5/2007 7:37:06 PM

Fetcher[
set{ xrange, high - low }
set{ tighten, COUNT( xrange 1 day ago > xrange , 1) }
set{ tight, days( tighten equal 0, 100) }

add column tight

/* VOLUME CALCULATIONS */
set{v, volume 1 day ago}
set{volinc, volume - v}
set{volpc, volinc / v}
set{volpct, volpc * 100}

set{VolZ, days(volume < 1,100)}
set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VlXvl, VolUp - VolDn}

set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdbl, days(vck < 2, 100)}

and add column VlXvl
and add column Vdbl
and add column volpct

/* END VOLUME CALCULATIONS */

tight above 0

VLXVL BELOW 0

LOW ABOVE LOW 1 DAY AGO
HIGH BELOW HIGH 1 DAY AGO

AVERAGE VOLUME(90) ABOVE 500000
AVERAGE VOLUME(90) ABOVE VOLUME

sort column 5 descending
]



Let's see if I can spot a dummy...LOL!

Notice the plot TIGHT... see what happens after it hits a high.

TheRumpledOne
6,359 posts
msg #57649
Ignore TheRumpledOne
modified
12/5/2007 7:50:34 PM

Fetcher[
/* SPOT THE DUMMY */

set{ xrange, high - low }
set{ tighten, COUNT( xrange 1 day ago > xrange , 1) }
set{ tight, days( tighten equal 0, 100) }

add column tight

/* VOLUME CALCULATIONS */
set{v, volume 1 day ago}
set{volinc, volume - v}
set{volpc, volinc / v}
set{volpct, volpc * 100}

set{VolZ, days(volume < 1,100)}
set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VlXvl, VolUp - VolDn}

set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdbl, days(vck < 2, 100)}

and add column VlXvl
and add column Vdbl
and add column volpct

/* END VOLUME CALCULATIONS */

tight EQUAL TIGHT 30 DAY HIGH

VLXVL BELOW 0

LOW ABOVE LOW 1 DAY AGO
HIGH BELOW HIGH 1 DAY AGO

AVERAGE VOLUME(90) ABOVE 500000
AVERAGE VOLUME(90) ABOVE VOLUME

sort column 5 descending
]




miketranz
715 posts
msg #57658
Ignore miketranz
12/5/2007 10:33:44 PM

Not a bad play on a risk/reward basis.The only problem is in real time,most "dummys",including myself especially,won't honor the stop no matter where it is.One of the hardest things to do as a trader,is learn how to scratch a trade.Its not what setup you're trading,its how you're trading the setup..........

TheRumpledOne
6,359 posts
msg #57666
Ignore TheRumpledOne
12/6/2007 12:45:47 AM

"Its not what setup you're trading,its how you're trading the setup.......... "

Dang that sounds kind of familiar!!

chetron
2,817 posts
msg #57676
Ignore chetron
modified
12/6/2007 7:02:04 AM

FOR THE BASIC FOLKS....



Fetcher[
/* SPOT THE DUMMY */

set{ xrange, high - low }
set{ tighten, COUNT( xrange 1 day ago > xrange , 1) }
set{ tight, days( tighten equal 0, 100) }

add column tight

/* VOLUME CALCULATIONS */
set{v, volume 1 day ago}
set{volinc, volume - v}
set{volpc, volinc / v}
set{volpct, volpc * 100}

set{VolZ, days(volume < 1,100)}
set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VlXvl, VolUp - VolDn}

set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdbl, days(vck < 2, 100)}

and add column VlXvl
and add column Vdbl
and add column volpct
AND ADD COLUMN TIGHT 30 DAY HIGH

DRAW TIGHT 30 DAY HIGH
/* END VOLUME CALCULATIONS */

/* tight EQUAL TIGHT 30 DAY HIGH */

VLXVL BELOW 0

LOW ABOVE LOW 1 DAY AGO
HIGH BELOW HIGH 1 DAY AGO

AVERAGE VOLUME(90) ABOVE 500000
AVERAGE VOLUME(90) ABOVE VOLUME

sort column 5 descending

]



Fetcher[


/* alf's dummy spot tampered with */


/* BRAND NEW Range Contraction/Expansion Scan Filter V v.2.5 */

/* PRICE PATTERNS */

/* Shark-32 (shark) --> (2 Consecutive Inside Days) */
set{IDhi_2, count(High 1 day ago is below High 2 days ago, 1)}
set{IDlo_2, count(Low 1 day ago is above Low 2 days ago, 1)}
set{IDhilo_2, IDhi_2 * IDlo_2}

set{IDhi_1, count(High is below High 1 day ago, 1)}
set{IDlo_1, count(Low is above Low 1 day ago, 1)}
set{IDhilo_1, IDhi_1 * IDlo_1}

set{ID21, IDhilo_2 * IDhilo_1}

/* --------------------------------------------- */

/* IDs (...id) (Inside Days -> H/L Range inside H/L Range 1 day ago) */
set{IDhi, count(High below High 1 day ago, 1)}
set{IDlo, count(Low above Low 1 day ago, 1)}
set{ID, IDhi * IDlo}

/* --------------------------------------------- */

/* NR7s (nr.7) (Narrowist Range of the last 7 days) */
set{NR7, count(Day Point Range reached a new 7 day Low, 1)}

/* ---------------------------------------------- */

/* NR4s (nr.4) (Narrowist Range of the last 4 days) */
set{NR4, count(Day Point Range reached a new 4 day Low, 1)}

/* ----------------------------------------------- */

/* Gaps (gap) (Unfilled Gaps) */
set{Gapup, count(Low is above High 1 day ago, 1)}
set{Gapdwn, count(High is below Low 1 day ago, 1)}
set{GapupORGapdwn, Gapup + Gapdwn}

/* ------------------------------------------------ */

/* Doji (doji) (H/L Rng above .20 w/Candle Body less than 30% of H/L Rng) */
set{HiLoRng, High - Low}
set{ClOpRng, abs(Close minus Open)}
set{ClOp_HiLo_ratio, ClOpRng / HiLoRng}
set{Range, count(HiLoRng is above .20, 1)}
set{Body, count(ClOp_HiLo_ratio is less than .30, 1)}
set{doji, Range * Body}

/* -------------------------------------------------- */

/* 8020 (8020) (Open AND Close take place at extremes in the Day Positions ...ie...Open>80%,Close<20% or, vice versa) */

/* Day Position Calculations for 80/20 Days */
set{Range1, High - Low}
set{CloLodiff, Close - Low}
set{OpLodiff, Open - Low}
set{dayposcl, CloLodiff / Range1}
set{dayposop, OpLodiff / Range1}

/* 80/20 Day with an UP Close */
set{dpCloUp, count(dayposcl is above .80, 1)}
set{dpOpUp, count(dayposop is below .20, 1)}
set{Up8020, dpCloUp * dpOpUp}

/* 80/20 Day with a DOWN Close */
set{dpOpDwn, count(dayposop is above .80, 1)}
set{dpCloDwn, count(dayposcl is below .20, 1)}
set{Dwn8020, dpOpDwn * dpCloDwn}
set{8020upORdwn, Up8020 + Dwn8020}

/* --------------------------------------------------- */

/* One Day Reversal (odr) (5 Day H / L w/Up or Down Close Above/Below 50% Day Position) */

/* ODR 50% Day Position Calculation */
set{HLrng, High - Low}
set{HLrng50, HLrng * .50}
set{DP50, Low + HLrng50}

/* ODR UP */
set{5daylo, count(Low reached a new 5 day Low, 1)}
set{ODR_UpClo, count(Close is above DP50, 1)}
set{ODR_Up, 5daylo * ODR_UpClo}

/* ODR DOWN */
set{5dayhi, count(High reached a new 5 day High, 1 )}
set{ODR_DwnClo, count(Close is below DP50, 1)}
set{ODR_Dwn, 5dayhi * ODR_DwnClo}

/* ODR UP or DOWN */
set{ODR_upORdwn, ODR_Up + ODR_Dwn}

/* ---------------------------------------------- */

/* ROC(2) Divergence (.div) (one day ROC2 pos/neg divergence with Close) */

/* ROC(2) Bullish Divergence Calculation */
set{3daylo, count(Low reached a new 3 day Low, 1)}
set{ROCdivpos1, count(ROC(2) above ROC(2) 1 day ago, 1)}
set{ROCdivpos2, count(ROC(2) 1 day ago below ROC(2) 2 days ago, 1)}
set{ROCbulldiv1, 3daylo * ROCdivpos1}
set{ROCbulldiv2, ROCbulldiv1 * ROCdivpos2}

/* ROC(2) Bearish Divergence Calculation*/
set{3dayhi, count(High reached a new 3 day High, 1)}
set{ROCdivneg1, count(ROC(2) below ROC(2) 1 day ago, 1)}
set{ROCdivneg2, count(ROC(2) 1 day ago above ROC(2) 2 days ago, 1)}
set{ROCbeardiv1, 3dayhi * ROCdivneg1}
set{ROCbeardiv2, ROCbeardiv1 * ROCdivneg2}

/* ROC(2) Bullish OR Bearish Divergence */
set{ROCbullORbeardiv, ROCbulldiv2 + ROCbeardiv2}

/* --------------------------------------------------- */

/* WR4s (wr.4) (Widest Range of the last 4 days) */
set{WR4, count(Day Point Range reached a new 4 day High, 1)}

/* ---------------------------------------------------- */

/* WR7s (wr.7) (Widest Range of the last 7 days) */
set{WR7, count(Day Point Range reached a new 7 day High, 1)}

/* ---------------------------------------------------- */

/* ODs (od) (Outside Days -> H/L Range outside H/L Range 1 day ago) */
set{ODhi, count(High above High 1 day ago, 1)}
set{ODlo, count(Low below Low 1 day ago, 1)}
set{OD, ODhi * ODlo}

/* ----------------------------------------------------- */

/* Windups (wup) (Outside Day followed by an Inside Day) */
set{WUp_ODhi, count(High 1 day ago above High 2 days ago, 1)}
set{WUp_ODlo, count(Low 1 day ago below Low 2 days ago, 1)}
set{WUp_ODhilo, WUp_ODhi * WUp_ODlo}

set{WUp_IDhi, count(High below High 1 day ago, 1)}
set{WUp_IDlo, count(Low above Low 1 day ago, 1)}
set{WUp_IDhilo, WUp_IDhi * WUp_IDlo}
set{WUp, WUp_ODhilo * WUp_IDhilo}

/* ------------------------------------------------------- */

/* Crable Hooks (hook) */

/* BULL Hook --> (Open above prev. High with Close below prev. Close & Range < prev. day's Range) */

set{RangeDWN, High - Low}
set{RangeDWN_1, High 1 day ago - Low 1 day ago}

set{RangeHookDWN, count(RangeDWN < RangeDWN_1, 1)}
set{OpenHookDWN, count(Open above High 1 day ago, 1)}
set{CloseHookDWN, count(Close below Close 1 day ago, 1)}

set{Hook_DWN_A, RangeHookDWN * OpenHookDWN}
set{BullHookDWN, Hook_DWN_A * CloseHookDWN}


/* BEAR Hook --> (Open below prev. Low with Close above prev. Close & Range < prev. day's Range) */
set{RangeUP, High - Low}
set{RangeUP_1, High 1 day ago - Low 1 day ago}

set{RangeHookUP, count(RangeUP < RangeUP_1, 1)}
set{OpenHookUP, count(Open below Low 1 day ago, 1)}
set{CloseHookUP, count(Close above Close 1 day ago, 1)}

set{Hook_UP_A, RangeHookUP * OpenHookUP}
set{BearHookUP, Hook_UP_A * CloseHookUP}


/* BearHookUP OR BullHookDOWN */
set{BearHookUPorBullHookDOWN, BearHookUP + BullHookDWN}

/* ------------------------------------------------- */

/* Stowell Naked Close (naked) */

/* Bull Naked LONG --> (Close below prev. Low with 10 day Slope of EMA(13) & 5 day Slope of Lows > 0) */

set{nakedTrendUP, count(10 day Slope of EMA(13) above 0, 1)}
set{nakedLo, count( 5 day Slope of Low above 0, 1)}
set{nakedClLow, count(Close below Low 1 day ago, 1)}

set{naked1, nakedTrendUP * nakedLo}
set{nakedLONG, naked1 * nakedClLow}


/* Bear Naked SHORT --> (Close above prev. High with 10 day Slope of EMA(13) & 5 day Slope of Highs < 0) */

set{nakedTrendDWN, count(10 day Slope of EMA(13) below 0, 1)}
set{nakedHi, count( 5 day Slope of High below 0, 1)}
set{nakedClHigh, count(Close above High 1 day ago, 1)}

set{naked2, nakedTrendDWN * nakedHi}
set{nakedSHORT, naked2 * nakedClHigh}

/* Naked Close LONG or SHORT */
set{nakedLoS, nakedLONG + nakedSHORT}

/* ----------------------------------------------------- */

/* Williams Hidden Smash (smash) */

/* HiLo Range */
set{HLrng1, High - Low}

/* Bull Hidden Smash LONG --> (Close above prev. Close but Close < 25% day pos. & Close < Open) */

/* Smash 25% Day Position Calculation */
set{HLrng25, HLrng1 * .25}
set{DP25, Low + HLrng25}

/* Bull Smash Fetch */
set{SmashCloA1, count(Close above Close 1 day ago,1)}
set{SmashCloB1, count(Close below Open, 1)}
set{SmashDP1, count(Close below DP25, 1)}

set{SmashA1, SmashCloA1 * SmashCloB1}
set{SmashA2, SmashA1 * SmashDP1}


/* Bear Hidden Smash SHORT --> (Close below prev. Close but Close > 75% day pos. & Close > Open) */

/* Smash 75% Day Position Calculation */
set{HLrng75, HLrng1 * .75}
set{DP75, Low + HLrng75}

/* Bear Smash Fetch */
set{SmashCloA11, count(Close below Close 1 day ago,1)}
set{SmashCloB11, count(Close above Open, 1)}
set{SmashDP11, count(Close above DP75, 1)}

set{SmashA11, SmashCloA11 * SmashCloB11}
set{SmashA22, SmashA11 * SmashDP11}

/* LONG or SHORT Hidden Smash */
set{LOS_HidSmash, SmashA2 + SmashA22}

/* --------------------------------------------------- */

/* PRICE ACTION STUFF ... AT A GLANCE */

/* Trend (short/intermediate/long-term) --> (trend) */
set{T13_34, count(EMA(13) above EMA(34), 1)}
set{T13_90, count(EMA(13) above EMA(90), 1)}
set{T34_90, count(EMA(34) above EMA(90), 1)}
set{T1, T13_34 * 1}
set{T2, T13_90 * 10}
set{T3, T34_90 * 100}
set{Trend12, T1 + T2}
set{Trend123, Trend12 + T3}

/* ------------------------------------------------------ */

/* 20 Day High/Low Breakout Check (20hilo) */

/* 20 day HIGH */
set{20dayhi, count(High reached a new 20 day High, 1 )}

/* 20 day LOW */
set{20daylo, count(Low reached a new 20 day Low, 1)}

/* 20 day HIGH or LOW */
set{20day_hiORlo, 20dayhi + 20daylo }

/* -------------------------------------------------- */

/* Consecutive days Close either Up(+) or Down(-) --> (..clo^) */
set{daysCloseUp, days(Close below Close 1 day ago,100)}
set{daysCloseDown, days(Close above Close 1 day ago,100)}
set{daysClosecurdir, daysCloseUp - daysCloseDown}

/* Consecutive days LOWS either Up(+) or Down(-) --> (..lo^) */
set{daysLOWSUp, days(Low below Low 1 day ago,100)}
set{daysLOWSDown, days(Low above Low 1 day ago,100)}
set{daysLOWScurdir, daysLOWSUp - daysLOWSDown}

/* Consecutive days HIGHS either Up(+) or Down(-) --> (..hi^) */
set{daysHIGHSUp, days(High below High 1 day ago,100)}
set{daysHIGHSDown, days(High above High 1 day ago,100)}
set{daysHIGHScurdir, daysHIGHSUp - daysHIGHSDown}

/* ----------------------------------------------------- */

/* Day Position Calculation (..dp) */
set{Range1a, High - Low}
set{CloLodiffa, Close - Low}
set{dayposcla, CloLodiffa / Range1a}

/* ------------------------------------------------------ */

/* DUMMY SPOT STUFF */

/* Consecutive days of Range Contraction / Expansion (rng^) */
set{dumRange, High - Low}
set{daysRngExpands, days(dumRange below dumRange 1 day ago,100)}
set{daysRngContacts, days(dumRange above dumRange 1 day ago,100)}
set{daysRngcurdir, daysRngExpands - daysRngContacts}

/* Consecutive days of Volume Contraction / Expansion (vol^) */
set{daysVolUp, days(Volume is below Volume 1 day ago,100)}
set{daysVolDn, days(Volume is above Volume 1 day ago,100)}
set{daysVolcurdir, daysVolUp - daysVolDn}

/* (A Dummy Spot is a Narrow Range Day, a Low Volume Day and an Inside Day - whose break allows you a low-risk entry in the direction of the prevailing trend.)*/

/*------------------------------------------------------- */

/* 2 PERIOD ROC STUFF */

/* ROC2 Pivot (rocpiv) */

/* ROC2 Pivot Calculation --> (Closing price (tomorrow) that will either maintain the current direction of the ROC(2) indicator...OR...turn it in the other direction) */

set{ROCpivA, Close - Close 2 days ago}
set{ROCpiv, ROCpivA + Close 1 day ago}


/* ROC2 Momentum (roc^) */

/* ROC2 Momentum Calculation --> Days ROC2 either Up(+) or Down(-) */
set{daysROCup, days(ROC(2) below ROC(2) 1 day ago,100)}
set{daysROCdwn, days(ROC(2) above ROC(2) 1 day ago,100)}
set{dayscurdir, daysROCup - daysROCdwn}

/* ------------------------------------------------------ */

/* TRADE ENTRY / EXIT STUFF */

/* Crable Opening Range Breakout (stretch)
(Average of the differences between the Open each day and the closest extreme (ie. H / L) to the Open each day over the previous 10 days...the stretch is then add. / subt. to today's Open giving price levels for either a Long / Short entry */

/* ORB STRETCH Calculations */
set{diff1, abs(Open minus High)}
set{diff2, abs(Open minus Low)}
set{stretch_diff, min(diff1,diff2)}

set{stretch_sum, sum(stretch_diff,10)}
set{stretch_avg10, stretch_sum / 10}


/* Profit Target (profit) -> (An amount based on 66% of a 10 day average of the H / L Range that when add. / subt. to entry gives a theoretical profit target ) */

/* Profit Target Calculations */
set{HiLo_rng, High minus Low}
set{HiLo_rngsum, sum(HiLo_rng,10)}
set{HiLo_rngavg, HiLo_rngsum / 10}

set{ProfTarget_66, HiLo_rngavg * .66}

/* ----------------------------------------------- */

/* TECHNICAL INDICATORS */

/* Defining my ROC(2) Indicator */
set{myROC, ROC(2)}

/* Defining myOSC(3,8) Indicator */
set{myOSC, EMA(3) - EMA(8)}

/* Defining trend(13) of myOSC(3,8) Indicator */
set{myOSCtrend, CEMA(myOSC,13)}

/* Defining my Multiple Moving Average TREND Indicator */
set{typprice_A, High 3 day High + Low 3 day Low}
set{typprice_sumA, typprice_A + Close}
set{typpriceA, typprice_sumA / 3}

/* (My version of Guppy MMAs...a sorta moving daily pivot based on today's Close & the 3 day Highs and Lows...displayed as an array of 2 groups of EMAs with different time frames) */

/* --------------------------------------------------------- */

/* SYMBOL SELECTION */

myosc < -0.74
DAYSvolcurdir < -1.5
DAYSrngcurdir < -1.5
CLOSE ABOVE 1
williams %r(2) increasing last 1 day
rsi(2) increasing last 1 day

/* ------------------------------------------ */

/* COLUMNS */

/* Columns (Trend Strength) */
add column separator
add column Stochastic %K(15,3,3)
add column dayposcla {..dp}
add column separator
add column separator
add column daysVolcurdir {vol^}
add column daysRngcurdir {rng^}

/* Columns (Patterns) */
add column separator
add column separator
add column MYOSC
add column ID {...id}
add column NR7 {nr.7}
add column NR4 {nr.4}
add column GapupORGapdwn {Gap}
add column doji
add column separator
add column 8020upORdwn {8020}
add column separator
add column ODR_upORdwn {ODR}
add column ROCbullORbeardiv {.DIV}
add column WUp
add column separator
add column separator
add column BearHookUPorBullHookDOWN {hook}
add column nakedLoS {naked}
add column LOS_HidSmash {smash}
add column separator
add column separator

/* Columns (ROC2 Momentum stuff) */
add column ROCpiv {ROCpiv}
add column dayscurdir {ROC^}
add column separator
add column separator

/* Crabel ORB stuff */
add column stretch_avg10{stretch}
add column ProfTarget_66{Profit}
add column separator
add column separator

/* ------------------------------------ */

/* INDICATORS */

/* Indicators MAs */
draw EMA(13)
draw EMA(34)
draw EMA(90)

/* Indicators Momentum and Trend */
draw myROC
draw myROC line at 0

draw RSI(2)

draw myOSC
draw myOSC line at 0


sort column 17 ascending
]



chetron
2,817 posts
msg #69568
Ignore chetron
12/4/2008 10:51:15 PM

POP

alf44
2,025 posts
msg #69584
Ignore alf44
12/5/2008 11:04:19 AM

"Dummy Spots" are Inside Days !

"Inside Days" represent "Range Contraction" !

-----------------------

Now where have I heard ..."Range Contraction" ?

Ahhhh....yes...I remember !!!


Regards,

alf44


chetron
2,817 posts
msg #69585
Ignore chetron
12/5/2008 11:16:36 AM

same cat, different knife

the dummy spot pick up a few that your scan missed the other day. fwiw


hth



StockFetcher Forums · Filter Exchange · What’s A Dummy Spot?<< 1 2 3 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus