StockFetcher Forums · Filter Exchange · new selection criterion<< >>Post Follow-up
billrider321
70 posts
msg #66245
Ignore billrider321
modified
8/15/2008 8:34:30 PM

can somebody guide me for this filters ..new to sf and loving it


FITER 1 -

( 100 * (C - C1) / C1) >= 8 AND V >3000

So we are looking for stock which is up 8% or more on 300000 plus volume.

Now to further reduce this list we take only stocks with 300% plus volume surge as compared to 100 day average volume. If you look at a scan for it in Telechart it would be:

(100 * V / AVGV100) >= 300


FILTER2 -

DT starting point is stocks which meet two conditions:

Up 100% plus from 52 week low. (where the stock has traded for less than 52 week, the low of the number of days the stock traded for)
Current price is within 25% of high price during the 100% plus move.
The second condition ensures that we only enter a trend which has resilience . A stock can go up 800% and retrace more than 25% and will still be 100% plus from 52 week low, but such stocks make poor candidates as their predominant trend has reversed.

Double Trouble cannot be scanned for in Telechart. You have to understand the conditions clearly to replicate it in other software's:




The stock currently is up 100% or more from its 52 week low. When stock has traded for less than 52 week, it has doubled from whatever period it traded for
It is within 25% of highest move during the rise from 52 week low or low of whatever period it traded for. (Please read this condition carefully and understand it. )

On the universe of stocks meeting above two conditions we apply our breakout plus weakness condition filter
( 100 * (C - C1) / C1) >= 4 AND V >= 1000 AND V > V1 and (100 * (C1 - C22) / C22) <= 10 and (100 * (C1 - C11) / C11)<= 10
This scan has four conditions:


4% breakout
Volume breakout
A month weakness condition
10 day weakness condition
On any given day this scan will give you 0 to20 candidates.

To narrow thsi list we use:

Volume surge
Distance from high during 100% move. Within 8% preferred.
Stock with highest and lowest yearly growth
Relative linearity.
Float


Modified Double Trouble


However many of you have trouble finding a software to do the exact calculations for Double Trouble. To overcome such problem here is a Modified Double Trouble method.
This is extremely Telechart friendly version.

We start with the relative strength scan

(C - AVGC135 ) / AVGC135

Select the top 5% ranked by the above scan value.

Apply liquidity condition:

AVGC20 * AVGV20 >= 2500

On that universe apply our universal breakout scan:

( 100 * (C - C1) / C1) >= 4 AND V >= 1000 AND V > V1 AND (100 * (C1 - C22) / C22) <= 10 AND (100 * (C1 - C11) / C11) <= 10




guru_trader
485 posts
msg #66296
Ignore guru_trader
modified
8/16/2008 7:43:11 PM

To get you started ...

Fetcher[
/* Filter 1 */
and not otcbb
and chart-length is 100 days

and price gained more than 8% in last 1 day
and volume gained more than 300% in last 1 day
]



Fetcher[
/* Filter 2 = "Double Trouble" */
and not otcbb
and chart-length is 100 days

and set{ 52wklow, low 52 week low }
and add column 52wklow
and draw 52wklow on plot price

and set{ close_diff, close - 52wklow }
and add column close_diff
and draw close_diff

and set{ close_diff_frac, close_diff / 52wklow }
and set{ close_diff_pct, close_diff_frac * 100 }
and add column close_diff_pct
and draw close_diff_pct

and close_diff_pct > 100
and close_diff_pct < 125
and sort column 7 descending

and price gained more than 4% in last 1 day
and volume gained more than 100% in last 1 days
and volume > volume 1 day ago

and set{ num1, close 1 day ago - close 22 days ago }
and set{ num2, num1 / close 22 days ago }
and set{ close_diff_22, num2 * 100 }
and add column close_diff_22
and close_diff_22 < 10

and set{ num3, close 1 day ago - close 11 days ago }
and set{ num4, num3 / close 11 days ago }
and set{ close_diff_11, num4 * 100 }
and add column close_diff_11
and close_diff_11 < 10
]



Fetcher[
/* Filter 3 = "Modified Double Trouble" */
and not otcbb
and chart-length is 100 days

and set{ close_diff_135, close - ma(135) }
and set{ relative_strength, close_diff_135 / ma(135) }
and add column relative_strength
and sort column 5 descending
and relative_strength > 0

and set{ ma20, ma(20) }
and set{ vol20, cma( volume, 20 ) }
and set{ liquity_condition, ma20 * vol20 }
and add column liquity_condition

and liquity_condition > 2500

and price gained more than 4% in last 1 day
and volume gained more than 100% in last 1 days
and volume > volume 1 day ago

and set{ num1, close 1 day ago - close 22 days ago }
and set{ num2, num1 / close 22 days ago }
and set{ close_diff_22, num2 * 100 }
and add column close_diff_22
and close_diff_22 < 10

and set{ num3, close 1 day ago - close 11 days ago }
and set{ num4, num3 / close 11 days ago }
and set{ close_diff_11, num4 * 100 }
and add column close_diff_11
and close_diff_11 < 10
]



StockFetcher Forums · Filter Exchange · new selection criterion<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus