StockFetcher Forums · Filter Exchange · RSI everything<< >>Post Follow-up
push5280
91 posts
msg #130917
Ignore push5280
modified
9/6/2016 8:03:52 PM

http://jayonthemarkets.com/2015/03/23/rsi-everything-part-1/
http://jayonthemarkets.com/2015/03/24/rsi-everything-part-2/
http://jayonthemarkets.com/2015/04/22/rsi-everything-calculations/

Fetcher[
/* RSI Everything Indicator by Jay Kaeppel */
/* There are four different indicators that are created then averaged together */
/* Each of the indicators is tagged seperately */

/* RSIALL adds the 2,3 and day RSI values and the devides them by 3 */
set{1a, RSI(2) + RSI(3)}
set{1b, 1a + RSI(4)}
set{RSIALL, 1b / 3}
/* RSIROC: calculate the 3-day change in the standard 3-day RSI value and add it to (the current 3-day RSI minus 50). RSIROC is a 2-day exponential average of that value. */
set{2a, RSI(3) 3 days ago - RSI(3)}
set{2b, RSI(3) - 50}
set{2c, 2a + 2b}
set{RSIROC, CEMA(2c,2)}
/* RSIq2: calculate the 3-day change in the standard 14-day RSI value and subtract it from (14-day RSI minus 50). RSIROC14 is a 2-day exponential average of that value. Add (14-day RSI minus 50) to RSIROC14 and multiply by 2 to get current RSIq2 value.*/
set{3a, RSI(14) 3 days ago - RSI(14)}
set{3b, RSI(14) - 50}
set{3c, 3b - 3a}
set{RSIROC14, CEMA(3c,2)}
set{3d, 3b + RSIROC14}
set{RSIq2, 3d * 2}
/* Indicator #4 is Tom Demark Range Expansion Index */
/* TDREI(period) */
set{ind4, TDREI(5)}
/* TD Everything: Add the four indicator values together and divide by 4, 50 is subtracted from RSIAll here to make 0 neutral as with the other indicators. RSIEverything is (((RSIAll-50) +RSIROC +RSIq2 +TDREI) / 4) */
set{5a, RSIALL -50}
set{5b, 5a + RSIROC}
set{5c, 5b + RSIq2}
set{5d, 5c + ind4}
set{RSIeverything, 5d / 4}
/*my indicators*/
set{myrange, high 52 week high / low 52 week low}
close > 1
average volume(90) > 250,000
myrange > 2
do not draw myrange
draw ma(126)
draw ma(63)
draw RSIeverything line at -64
draw RSIeverything line at -32
draw RSIeverything line at 0
draw RSIeverything line at 32
draw RSIeverything line at 64
draw RSI(2) line at 10
draw RSI(2) line at 90
draw CCI(4) line at 0
draw CCI(4) line at 130
draw CCI(4) line at -130
add column myrange
add column RSIALL
sort by column five descending
chart-time is 6 months]

compound_gains
135 posts
msg #130922
Ignore compound_gains
9/7/2016 9:17:44 AM

Notes:
*This method is probably best used with sector ETFs and index ETFs rather than with individual stocks – but traders are encouraged to experiment.

The Setup

At the end of the current week:

The 5-week simple moving average is above the 55-week exponential moving average.
RSI Everything registers a weekly close of -32 or below.

The Trigger

Buy shares or the ETF (or stock) in question when it hits the previous week’s high price plus $0.02 per share.

The Exit

Close the trade at a profit on the first profitable weekly close.
Close the trade at a loss if price falls $0.02 or more below the previous week’s two week low.
Close the trade – whether at a profit or a loss – if the 5-week simple moving average closes below the 55-week exponential moving average.

More Notes

*A trader might also consider using a hard percentage of trading capital stop to cut a loss rather than waiting for the two week low to be hit.

*It may take a few weeks after the initial setup before price actually triggers an entry signal by taking out the previous week’s high.

compound_gains
135 posts
msg #130926
Ignore compound_gains
modified
9/7/2016 10:38:26 AM

Couple of calculation errors...RSIROC and RSIq2

Fetcher[
/* RSI Everything Indicator by Jay Kaeppel */
/* There are four different indicators that are created then averaged together */
/* Each of the indicators is tagged seperately */

/* RSIALL adds the 2,3 and 4 day RSI values and then devides them by 3 */
set{1a, RSI(2) + RSI(3)}
set{1b, 1a + RSI(4)}
set{RSIALL, 1b / 3}
/* RSIROC: calculate the 3-day change in the standard 3-day RSI value and add it to (the current 3-day RSI minus 50). RSIROC is a 2-day exponential average of that value. */
set{2a, RSI(3) - RSI(3) 3 days ago} /*VARIABLES NEEDED TO BE FLIPPED*/
set{2b, RSI(3) - 50}
set{2c, 2a + 2b}
set{RSIROC, CEMA(2c,2)}
/* RSIq2: calculate the 3-day change in the standard 14-day RSI value and subtract it from (14-day RSI minus 50). RSIROC14 is a 2-day exponential average of that value. Add (14-day RSI minus 50) to RSIROC14 and multiply by 2 to get current RSIq2 value.*/
set{3a, RSI(14) - RSI(14) 3 days ago} /*VARIABLES NEEDED TO BE FLIPPED*/
set{3b, RSI(14) - 50}
set{3c, 3b - 3a}
set{RSIROC14, CEMA(3c,2)}
set{3d, 3b + RSIROC14}
set{RSIq2, 3d * 2}
/* Indicator #4 is Tom Demark Range Expansion Index */
/* TDREI(period) */
set{ind4, TDREI(5)}
/* TD Everything: Add the four indicator values together and divide by 4, 50 is subtracted from RSIAll here to make 0 neutral as with the other indicators. RSIEverything is (((RSIAll-50) +RSIROC +RSIq2 +TDREI) / 4) */
set{5a, RSIALL -50}
set{5b, 5a + RSIROC}
set{5c, 5b + RSIq2}
set{5d, 5c + ind4}
set{RSIeverything, 5d / 4}
/*my indicators*/
set{myrange, high 52 week high / low 52 week low}
close > 1
average volume(90) > 250,000
myrange > 2
weekly ma(5) above weekly ema(55) */*********/
rsieverything below -31.99 */*********/
etf */*********/
do not draw myrange
draw ma(126)
draw ma(63)
draw RSIeverything line at -64
draw RSIeverything line at -32
draw RSIeverything line at 0
draw RSIeverything line at 32
draw RSIeverything line at 64
draw RSI(2) line at 10
draw RSI(2) line at 90
draw CCI(4) line at 0
draw CCI(4) line at 130
draw CCI(4) line at -130
add column myrange
add column RSIALL
add column rsieverything
set{entry, high 5 day high + .02}
draw price line at entry on plot price
sort by column five descending
chart-time is 6 months]

push5280
91 posts
msg #130941
Ignore push5280
9/7/2016 3:00:22 PM

Compound_gains good eye, thanks for the corrections

StockFetcher Forums · Filter Exchange · RSI everything<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus