StockFetcher Forums · General Discussion · Weekly Statistics<< >>Post Follow-up
daybuck
19 posts
msg #121290
Ignore daybuck
8/8/2014 7:09:16 PM

I have been searching all of TRO's stat scans but have not been able to find a WEEKLY stat filter that has the same information as the daily "travel guide" that TRO produced. I was hoping to find the same info just based on a weeks info instead of the daily info. Any help locating it (if it exists) would be much appreciated.

guru_trader
485 posts
msg #121295
Ignore guru_trader
8/11/2014 2:03:23 AM

Can you post the daily "travel guide" version you like so that we can see about converting it to a weekly version?

Mactheriverrat
1,328 posts
msg #121296
Ignore Mactheriverrat
modified
8/11/2014 2:56:04 AM

add below to the daily filter

Chart-display is weekly

daybuck
19 posts
msg #121304
Ignore daybuck
8/11/2014 11:36:03 AM

Here is Avery's "stat scan travel guide".....I am looking for the same thing with weekly statistics instead of daily since I can't trade daily. The idea is to plug your stock into the symlist and get the stats for that stock. Simply changing the chart display to weekly isn't gonna get the weekly stats.

* TRO STAT SCAN - TRAVEL GUIDE - POCKET EDITION in cents */

set{xRange, high - low}
set{AvgRng, cma(xRange,5) }

set{HiOp, High - Open }
set{RunPCT, HiOp}
set{AvgRun5, cma(RunPCT,5) }
set{AvgRun20, cma(RunPCT,20) }

set{HiCl, High - Close }
set{PBPCT, HiCl}
set{AvgPB5, cma(PBPCT,5) }
set{AvgPB20, cma(PBPCT,20) }

set{ClLo, Close - low }
set{BouncePCT, ClLo }
set{AvgBounce5, cma(BouncePCT,5) }
set{AvgBounce20, cma(BouncePCT,20) }

set{OpLo, Open - low}
set{DropPCT, OpLo }
set{AvgDrop5, cma(DropPCT,5) }
set{AvgDrop20, cma(DropPCT,20) }

set{Green, count( close > open , 100)}

set{B10A, count(RunPCT > .10 , 100)}

set{A10A, count(RunPCT > .10 , 1)}
set{chg, sum( A10A - A10A 1 day ago ,5)}


and add column separator
add column RunPCT{R(today)}

add column PBPCT{P(today)}

add column DropPCT{D(today)}

add column BouncePCT{B(today)}


and add column separator
and add column AvgRun5
and add column AvgDrop5
and add column AvgBounce5
and add column AvgPB5
and add column AvgRun20
and add column AvgDrop20
and add column AvgBounce20
and add column AvgPB20

/* SELECTION CRITERIA */

symlist(biof)

sort column 1 Ascending




daybuck
19 posts
msg #121329
Ignore daybuck
8/13/2014 10:00:34 PM

Any Ideas???

Mactheriverrat
1,328 posts
msg #121330
Ignore Mactheriverrat
8/14/2014 3:11:59 AM

Search google for
The Rumpled One
He posts youtube every couple of days and he will respond to any posts


guru_trader
485 posts
msg #121447
Ignore guru_trader
modified
9/5/2014 3:17:50 AM

Check the values, but this should get you started ...

Fetcher[

/* === TRO STAT SCAN - TRAVEL GUIDE - WEEKLY POCKET EDITION in cents === */

/* === Charting === */
chart-length is 6 months
chart-display is weekly
chart-type is candlestick

/* === Selection Criteria === */
add column exchange
market is nasdaq
/* symlist(biof) */

/* === Sorting === */
sort column 4 descending

/* === weekly offset === */
/* Why do my weekly measures not match filter results? ... http://help.stockfetcher.com/sfhelp/?id=100296 */
/* to be safe, always use last Friday or Saturday's date as the date offset */
date offset 8/29/2014

/* === display last week's OHLC === */
/* add column weekly open {w.open} */
/* add column weekly high {w.high} */
/* add column weekly low {w.low} */
/* add column weekly close {w.close} */

/* === main filter === */

set{xRange, weekly high - weekly low}
set{AvgRng, cma(xRange,5)}

set{hiop, weekly high - weekly open}
set{RunPCT, hiop}
set{AvgRun5, cma(RunPCT,5)}
set{AvgRun20, cma(RunPCT,20)}

set{hicl, weekly high - weekly close}
set{PBPCT, hicl}
set{AvgPB5, cma(PBPCT,5)}
set{AvgPB20, cma(PBPCT,20)}

set{cllo, weekly close - weekly low}
set{BouncePCT, cllo}
set{AvgBounce5, cma(BouncePCT,5)}
set{AvgBounce20, cma(BouncePCT,20)}

set{oplo, weekly open - weekly low}
set{DropPCT, oplo}
set{AvgDrop5, cma(DropPCT,5)}
set{AvgDrop20, cma(DropPCT,20)}

set{Green, count(weekly close > weekly open , 100)}
set{B10A, count(RunPCT > .10 , 100)}
set{A10A, count(RunPCT > .10 , 1)}
set{chg, sum(A10A - A10A 1 week ago ,5)}

and add column separator

add column Green
add column B10A
add column A10A
add column chg

and add column separator

add column RunPCT {R}
add column PBPCT {P}
add column DropPCT {D}
add column BouncePCT {B}

and add column separator

and add column AvgRun5
and add column AvgDrop5
and add column AvgBounce5
and add column AvgPB5

and add column separator

and add column AvgRun20
and add column AvgDrop20
and add column AvgBounce20
and add column AvgPB20

and add column separator

]

StockFetcher Forums · General Discussion · Weekly Statistics<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus