StockFetcher Forums · Public Filter List · George Angells Buy and Sell Zones la LSS Three-Day Cycle<< >>Post Follow-up
nikoschopen
2,824 posts
msg #41467
Ignore nikoschopen
2/21/2006 9:29:01 PM

LSS, which stands for Long, Short, and Sell short, is based on George Douglas Taylor's "book Method". For Taylor, the three days consisted of a so-called buy day, a sell day, and a short-sell day. On the buy day, the low was made first near the prior day's low and the market would rally. On the sell day, there would be a lot of trading activity near the prior day's high. On the sell-short day, the high was made first providing the opportunity to sell before the market broke. Finally, with prices trading near the short-sell day low, prices would be manipulated lower to provide another buying opportunity for the smart money on the third day. Well, at least, that's the theory.

This filter, by itself, is not very useful. However, when used in conjuction with your preexisting filters, it will enable you to find potential areas of support and resistance as well as the anticipated range for the next day based on recent price actions.

There are four key calculations involved in calculating the buy and the sell zones:
1) The rally number (RN): today's high minus yesterday's low
2) The decline number (DN): yesterday's high minus today's low
3) The buying high number (BH): today's high minus yesterday's high
4) The buying under number (BU): yesterday's low minus today's low


______________

SELL ENVELOPE

1) The rally number

set{RN, high - low 1 day ago}
set{3RN, sum(RN,3) / 3}
set{RR1, 3RN + low}

2) Today's high (RR2)

3) The buying high number

set{BH, high - high 1 day ago}
set{3BH, sum(BH,3) / 3}
set{RR3, 3BH + high}

4) LSS pivot breakout buy (RR4)

2 * Pivot Point - Low

5) The average of the above 4 numbers

______________

BUY ENVELOPE

set{DN, high 1 day ago - low}
set{3DN, sum(DN,3) / 3}
set{SS1, high - 3DN}

2) Today's low (SS2)

3) The buying under number

set{BU, low 1 day ago - low}
set{3BU, sum(BU,3) / 3}
set{SS3, low - 3BU}

4) LSS pivot breakout sell (SS4)

2 * Pivot Point - high

5) The average of the above 4 numbers


Explanation: Buy and sell envelopes are both comprised of 4 numbers, which are possible support and resistance numbers where the stock should stop advancing or declining based on recent price action. Averages, on the other hand, are used to figure out the anticipated range for the next day. You simply take their difference to come up with the number.

Fetcher[
/*SELL ENVELOPE*/

set{RN, high - low 1 day ago}
set{3RN, sum(RN,3) / 3}
set{RR1, 3RN + low}

set{RR2, high}

set{BH, high - high 1 day ago}
set{3BH, sum(BH,3) / 3}
set{RR3, 3BH + high}

set{RR4, R1}

set{RRadd1, RR1 + high}
set{RRadd2, RR3 + R1}
set{RRadd, RRadd1 + RRadd2}
set{RRavg, RRadd / 4}

/*BUY ENVELOPE*/

set{DN, high 1 day ago - low}
set{3DN, sum(DN,3) / 3}
set{SS1, high - 3DN}

set{SS2, low}

set{BU, low 1 day ago - low}
set{3BU, sum(BU,3) / 3}
set{SS3, low - 3BU}

set{SS4, S1}

set{SSadd1, SS1 + low}
set{SSadd2, SS3 + S1}
set{SSadd, SSadd1 + SSadd2}
set{SSavg, SSadd / 4}

set{range, RRavg - SSavg}

add column RR1
add column RR2
add column RR3
add column RR4

add column SS1
add column SS2
add column SS3
add column SS4

add column range

draw RR1 on plot price
draw RR2 on plot price
draw RR3 on plot price
draw RR4 on plot price
draw SS1 on plot price
draw SS2 on plot price
draw SS3 on plot price
draw ss4 on plot price
draw range

chart-time is 2 weeks
]


NOTE: Nine columns are added. Columns 1-4 (RR1 - RR4) refer to resistance numbers; columns 5-8 (SS1 - SS4) to suport numbers. The final column, range, refers to the anticipated range for the next trading session.


StockFetcher Forums · Public Filter List · George Angells Buy and Sell Zones la LSS Three-Day Cycle<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2016 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus