StockFetcher Forums · Filter Exchange · New here and looking for a specific filter<< >>Post Follow-up
reiazh
2 posts
msg #160801
- Ignore reiazh		 1/27/2024 9:55:58 PM

Hi all. Joined SF today and started reading the user guide. A little daunting as I'm just starting. Hoping someone can help with a filter as follows:

All stocks over $10
Daily volume over 300K
Stock moves either up or down 10% from the close three days ago
I'm looking to get historical information so it would have to show results accordingly

Thanks in advance for your help!

lorypanna
16 posts
msg #160802
- Ignore lorypanna		 1/28/2024 10:51:11 AM

Hi.
Hope this can help.
Comments try to explain what my understanding was and what I wanted to do.
Not an expert here, so the filter could identify wrong stocks. Moreover, there are many expert members who likely can do a better/simpler coding of the filter.
JFY, I have and 'advanced' subscription: I cannot know if the filter can run with the 'basic' subscription (it doesn't run in the free site). In any case it can give you an idea of the available commands and syntax.
Have a nice day.

Fetcher[
chart-time is 12 months

/* Interesting exchanges are NASDAQ and NYSE */
set {IsNSDQ, count(market is NASDAQ, 1)}
set {IsNYSE, count(market is NYSE, 1)}
set {ExchangeOfInterest, IsNSDQ + IsNYSE}
ExchangeOfInterest is above 0

/* ETFs are identified */
set {IsETF, count(stock type is ETF, 1)}
IsETF is equal 0

/* Conditions on close-price and volume (average 50-day volume is considered) */
set{MyCloseFlag, count(close is above 10.0, 1)}
set{MyAvgVolFlag, count(cma(volume, 50) is above 300000.0, 1)}

/* Conditions on close-price % diff relative to 3 days before */
set{MyCloseDiffPerc3Tmp1, close - close 3 days ago}
set{MyCloseDiffPerc3Tmp2, MyCloseDiffPerc3Tmp1 divided by close 3 days ago}
set{MyCloseDiffPerc3, 100.0 * MyCloseDiffPerc3Tmp2}
set{MyClose3Up10Flag, count(MyCloseDiffPerc3 is above 10.0, 1)}
set{MyClose3Down10Flag, count(MyCloseDiffPerc3 is below -10.0, 1)}

/* Conditions are summed. MyInterestingTmp2 is for identifying up-10%, MyInterestingTmp3 is for identifying down-10% */
set{MyInterestingTmp1, MyCloseFlag plus MyAvgVolFlag}
set{MyInterestingTmp2, MyInterestingTmp1 plus MyClose3Up10Flag}
set{MyInterestingTmp3, MyInterestingTmp1 plus MyClose3Down10Flag}

/* Interesting stocks are the ones with MyInterestingTmp2 or MyInterestingTmp3 valued 3 at least once in the last 1 year (252 days) */
set{MyInterestingUp1Y, count(MyInterestingTmp2 equals 3, 252)}
set{MyInterestingDown1Y, count(MyInterestingTmp3 equals 3, 252)}
set{MyInteresting1Y, MyInterestingUp1Y + MyInterestingDown1Y}
MyInteresting1Y is above 0

/* Interesting stocks' indicators */
set{Up10P3D, count(MyInterestingTmp2 equals 3, 1)}
set{Down10P3D, count(MyInterestingTmp3 equals 3, 1) * -1}

/* Exchange, ETF flag */
add column IsNSDQ
add column IsNYSE
add column IsETF

/* Columns with the count of up-10% / down-10% in the last 1 year */
add column MyInterestingUp1Y
add column MyInterestingDown1Y
sort column 8 descending

/* Average 50-day volume is plotted */
draw cma(volume, 50) on plot volume

/* Interesting stocks' indicators are plotted */
draw Up10P3D
draw Down10P3D on plot Up10P3D
PlotType{Up10P3D, line}
PlotType{Down10P3D, line}

/* Indicators to be excluded from plotting */
do not draw ExchangeOfInterest
do not draw IsNSDQ
do not draw IsNYSE
do not draw IsETF
do not draw MyInteresting1Y
]
xarlor
562 posts
msg #160803
- Ignore xarlor		 1/28/2024 1:10:19 PM

Fetcher[
close > 10
average volume(252) > 300,000
set{10u,close 3 days ago * 1.10}
set{10d,close 3 days ago *.90}
set{up10,count(close > 10u,1)}
set{down10,count(close < 10d,1)}
set{trigger,up10 + down10}
up10 > -1
down10 > -1
trigger > 0

do not draw trigger

add column close 3 days ago
add column 10u
add column 10d
]
reiazh
2 posts
msg #160805
- Ignore reiazh		 1/29/2024 9:34:19 AM

Thanks @lorypanna and @xarlor for your responses. I really appreciate your expertise and the time taken in doing the filters.
StockFetcher Forums · Filter Exchange · New here and looking for a specific filter<< >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.