StockFetcher Forums · Filter Exchange · The Ron Groenke V Theory<< 1 2 >>Post Follow-up
jimvin
170 posts
msg #139361
Ignore jimvin
modified
11/16/2017 3:22:28 PM

SAFeTRADE, I say with no false modesty that in general one would be better of asking a Magic 8-Ball for stock advice than requesting my opinion; I am by no means one of the demonstrated (and in some cases elf-proclaimed) gurus on this board...

For what its worth, the raw Groenke model picks all suggest negatives on JPM, CSCO, XLF, and KBE. SPY looks like a careful positive...

My 11 herbs and spices over-lay points to the same conclusions, but it reflects my short-term trading strategy (in on Monday at Market Open at Open Price, out no later than 3:30 Friday or when desired profit is reached 1% to 2% depending on the Market temperature that week; never after Monday).

Of course none of this means that you shouldn't buy stock picks if you believe strongly in your trading method and model.

My bastardized Groenke plays this week were BRS and OSTK for about a 5% gain by Monday close (they've dropped appreciably Tuesday and today as the Market cratered); over the 10 weeks I've been tracking my current variation I've only lost money twice and both times it was in the very low 100s....

Stay tuned, those who dare or care, for updates as warranted.

SAFeTRADE
630 posts
msg #139366
Ignore SAFeTRADE
11/16/2017 10:39:00 PM

Thanks Jim. I have not traded off this filter recently only called what the method looks for.
The range on this market is widening and I do not have a cast iron stomach to trade it.

Always interested in what and how others are doing.

Safetrade

Lapre506
48 posts
msg #139390
Ignore Lapre506
11/17/2017 6:43:28 PM

Jim can you post your version (clickable) so I can give it a look?

jdinkel
4 posts
msg #140165
Ignore jdinkel
modified
12/17/2017 2:48:56 PM

Nice job guys.

Update on how to post a Fetcher[] link... I found a [link](http://www.stockfetcher.com/help/What-are-the-StockFetcher-forums/100302) explaining how to post a filter. The preview works, but only if you haven't used [] characters in your script comments. I notice most people here are not too keen on comments, but I need them. Too easy to forget how something works without a clear map. Hope that I'm not the only one that finds this useful.

Here's my version. Perhaps somebody will be kind enough to help me with those questions in the script. There are additional details that Ron publishes in his book Show me the Trade in chapter 2. So perhaps go over those if you want to use his latest version. I tried to incorporate them here.

Fetcher[
/* Another member: http://www.stockfetcher.com/forums///54752/-1/54752 */
/* SAFeTRADE: http://www.stockfetcher.com/forums2/Filter-Exchange/The-Ron-Groenke-V-Theory/124548/-1/124548 */
/**** Calculate the Lower 25 as lower25 = 0.25 x (52 week high - 52 week low) */
set{hi52w, High is 52 week High} /* Step 1 - get 52 week high for underlying */
set{lo52wVpointA, Low is 52 week Low} /* Step 2 - get 52 week low for underlying */
set{range52w, hi52w-lo52wVpointA} /* Step 3 - Calculate the range from low to high */
set{lower25, range52w * 0.25} /* Step 4 - Calculate the bottom quarter of the range */
/**** Calculate the Buy Limit as BL = Buy Limit = 52 week low + lower25 */
set{buylimit, lower25 + lo52wVpointA} /* Step 5 - BL - Buy Limit - The max price you should pay for the stock. */
/**** Calculate the Buy Rank as 10 x ( (buylimit - close) / lower25 ) where close is the current price */
set{blcl, buylimit - close}
set{brTop, blcl * 10}
set{buyrank, brTop / lower25}
/**** Calcualte the Take Action Indicator as tai = buyrank x (1 + FDA/(2 x FDA - close)) */

set{fda, MA(50)} /* FDA = 50 day moving average */
set{2fda, 2*fda}
set{2fdacp, 2fda - close}
set{fdadiv, fda / 2fdacp}
set{fdaplus, 1 + fdadiv}
set{tai, buyrank * fdaplus} /* Get Ready >=10, Take action >=-5 & <10, Wait >=-10 & < -5, Bad Idea <-10 */

find optionable stocks
/* From Show me the Trade Ch2 - Trading in the V 20 days or more */
and the count(tai > -5,25) is above 20
and the count(tai <= 10,25) is above 20
/* From Show me the Trade Ch2 - Stock is going up last 3 days */
close has been increasing for 3 days

/* Probably best to keep the trading to stocks that can have a few strikes below ATM */
and the price is more than 10

and add column hi52w
and add column lo52wVpointA
and add column buylimit
and add column buyrank
and add column tai
/* Great idea from SAFeTRADE to add a graph of the tai with the indicators as sortable columns */
set{gr, count(tai above 10,1)}
set{ta, count(tai between -5 and 10,1)}
set{wait, count(tai between -10 and -5,1)}
set{bad_idea, count(tai below -10,1)}
add column gr{get_ready}
add column ta{take_action}
add column wait
add column bad_idea
add column separator
sort column 12 descending /* take action indicator > 1 to the top*/

/* Plot the take action indicator and show the trading indicator lines. We are looking for anything between -5 and 10 */
draw tai line at 10
draw tai line at -5
draw tai line at -10

/* Calculate the Gold $ Calculation */
/* 10 x number of up days + 2 x number of days in Vision View V + 30 or 0 */
/* 30 if the stock is in the Visions View V or price in the 50 day average range, 0 if it is not. */
/* The ideal case is when the stock is trading in the Visions View V for 20 days, going up the last three days, and within 5% of the 50 day moving average. */
set{fda5pctabove, fda * 1.05}
set{fda5pctbelow, fda * 0.95}
draw fda
draw fda line at fda5pctabove
draw fda line at fda5pctbelow
set{cntUnder, count(fda < fda5pctabove,20)}
set{cntAbove, count(fda > fda5pctbelow,20)}
set{aggregate, cntUnder + cntAbove}
/*set{trigger, count(aggregate>1,20)}
draw trigger*/
/* what am I doing wrong? out of variables? */



draw ta /* Creates a nice set of dots, one for each day where the trade meets the criteria - I find it easier to see than the lines */
]



SAFeTRADE
630 posts
msg #140167
Ignore SAFeTRADE
12/17/2017 4:44:59 PM

Here is a simplified version of The V Theory. Look for take_action to be 1 and visually inspect the charts.

Also if I reread the rules properly all it takes is 1 of 3 conditions to be true.

1. Price within V for 20 days
2. Price within 5% + or - of the ma(50)
or
3. Currently in the V

That's all there is to it.

Fetcher[ Set{bla, high 10 day high - low 10 day low}
set{blb, bla * .25}
set{bl, low 10 day low + blb}

set{bra, bl - close}
set{brb, bra / blb}
set{br, 10 * brb}

set{taa, ma(20) * 2}
set{tab, taa - close}
set{tac, ma(20) / tab }
set{tad, tac + 1}
set{tai, br * tad}

set{pointb1, bla * .125}
set{pointb, bl + pointb1}

set{pointc, low 10 day low + pointb1}
set{cls, close}
set{m50u, ma(50) * 1.05}
set{m50d, ma(50) * .95}
set{m50, count(close above m50d,1) * count(close below m50u,1)}
set{ta, count(Williams %R(16) crossed above -20,1)}
set{take_action, m50 * ta}

s&p 500

draw pointc on plot cls
draw pointb on plot cls
draw m50u on plot cls
draw m50d on plot cls
draw ta
draw Williams %R(16)
add column m50
add column ta
add column take_action
add column Williams %R(16)
sort column 7 descending
]













jimvin
170 posts
msg #140352
Ignore jimvin
12/23/2017 3:32:25 PM

lapre506:

Sorry for the delay; an outpatient surgery turned into an extended hospital stay...
That said, below is the version of the model I'm using for test (emphasis on that last word; I am only paper-trading this).

Fetcher[ market is not otcbb
not etf
and stock is optionable
Close > 3
Average Volume(30)> 300000

Set{bla, high 10 day high - low 10 day low}
set{blb, bla * .25}
set{bl, low 10 day low + blb}

set{bra, bl - close}
set{brb, bra / blb}
set{br, 10 * brb}

set{taa, ma(20) * 2}
set{tab, taa - close}
set{tac, ma(20) / tab }
set{tad, tac + 1}
set{tai, br * tad}

set{pointb1, bla * .125}
set{pointb, bl + pointb1}

set{pointc, low 10 day low + pointb1}

set{MBB%, Ma(20) / bl}
set{UBB%, upper bollinger band(20,2) / bl}
set{cls, close}
add column tai
add column bl
add column ma(20){MBB}
add column mBB%
add column upper bollinger band(20,2){UBB}
add column UBB%

draw tai line at 10
draw tai line at -5
draw tai line at -31

draw bl on plot price

draw pointb on plot cls
draw pointc on plot cls

draw ma(20)

draw Bollinger %B(20,2) line at .65
draw Bollinger %B(20,2) line at .23

set{gr, count(tai above 10,1)}
set{ta, count(tai between -5 and 10,1)}
set{wait, count(tai between -10 and -4.9,1)}
set{bad_idea, count(tai below -10,1)}
add column gr{get_ready}
add column ta{take_action}
add column wait
add column bad_idea

set{a, close - close 50 days ago}
set{b, a / close}
set{c, b * 100}

set{bi?, count(close crossed above low 2 days ago,1)}/*Bottom Indicator*/
draw bi?
add column c{alpha}
add column bi?/*With Bollinger %B(20,2) crossing .23 or .65*/
add column Bollinger %B(20,2)

SET{VAR1,COUNT(DAY RANGE ABOVE Average Day Range(30),1)}
Add column VAR1

Draw weekly ift(3,1) line at .90
Add column weekly ift(3,1)

draw aroon up(10)
add column aroon(10)

Add column Williams %r(14)

Draw Darvas Box

Draw MACD

set{macdf, MACD Fast Line(3,6,9)}
set{macds, MACD Slow Line(3,6,9)}
set{n, 0}

set{buy, count(macdf crossed above macds,1)}
set{sell, count(macdf crossed below macds,1)}

draw macds on plot n
draw macdf on plot n

draw sell on plot buy

Add column Buy

Add column sector

sort column 3 descending
]




StockFetcher Forums · Filter Exchange · The Ron Groenke V Theory<< 1 2 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.