StockFetcher Forums · General Discussion · volume increase<< >>Post Follow-up
cjmins
3 posts
msg #38364
Ignore cjmins
10/7/2005 12:50:58 AM

I'm new and I would like to know how to write (volume is 150% of yesterdays volume). I wrote volume is 50% greater than 1 day ago but I don't think it works.
Thanks


MikeB60046
43 posts
msg #38365
Ignore MikeB60046
10/7/2005 6:02:02 AM

volume is 150% above volume 1 day ago


TheRumpledOne
6,407 posts
msg #38366
Ignore TheRumpledOne
10/7/2005 12:36:21 PM

Fetcher[

/* STOCK VOLUME DISPLAY */

/* ClxCl - number of consecutive days close increasing(+)/decreasing(-) */

set{CCb,days(close is above close 1 day ago,100)}
set{CCa,days(close is below close 1 day ago,100)}
set{ClxCl, CCa - CCb}

/* volpct - percentage volume increased(+)/decreased(-) */
set{v, volume 1 day ago}
set{volinc, volume - v}
set{volpc, volinc / v}
set{volpct, volpc * 100}

/* Volz - Number of zero volume days out of last 100 days ... -1 means none */
set{VolZ, days(volume < 1,100)}

/* VlxVl - number of consecutive days volume increasing(+)/decreasing(-) */
set{VolUp, days(volume is below volume 1 day ago,100)}
set{VolDn, days(volume is above volume 1 day ago,100)}
set{VlxVl, VolUp - VolDn}

/* vdbl - consecutive days volume at least doubled */
set{vck1, volume 1 day ago }
set{vck, volume / vck1 }
set{vdays, days(vck < 2, 100)}

/* VHIGH - number days volume equal volume 10 day high */
set{VHIGH, COUNT(volume equal volume 10 day high, 1)}

/* VLOW - number days volume equal volume 10 day low */
set{VLOW, COUNT(volume equal volume 10 day low, 1)}

/* VxVAV - number of consecutive days volume above(+)/below(-) avg volume */
set{VavUp, days(volume is below average volume(10),100)}
set{VavDn, days(volume is above average volume(10),100)}
set{VxVAV, VavUp - VavDn}


add column volpct

add column ClxCl
add column VlxVl

add column Vdays {Vdbl}

add column VolZ

add column VxVAV

add column VHIGH
add column VLOW

/* YOUR SELECTION CRITERIA GOES BELOW THIS LINE */

volpct above 100

close above 20

VOLUME ABOVE 1000000

SORT COLUMN 5 DESCENDING

/* YOUR SELECTION CRITERIA GOES ABOVE THIS LINE */
]



Everyting you wanted to know about volume.

MAY ALL YOUR FILLS BE COMPLETE.


alf44
2,025 posts
msg #38402
Ignore alf44
10/11/2005 2:05:36 PM

Here's a simple scan to find stocks that have Closed above the Highs of the last 2 days...with a 175% increase in Volume above the Average Volume(20)...

-------------------

Fetcher[/* Close above Highs of last 2 days w/175% increase over AvgVol(20) */

set{avgVol_20, Average Volume(20)}
set{VolA, Volume / avgVol_20}
set{VolB, VolA - 1}
set{Volpct_incr, VolB * 100}

Show all stocks where

Close is above High 2 days ago and
Close is above High 1 day ago and
Volpct_incr is above 175 and
Average Volume(20) is above 100000 and
Price is above 2

and add column Average Volume(20) {avgVol_20}
and add column Volpct_incr
]



---------------------

It's simple but VERY effective ! imo


Regards,

alf44





alf44
2,025 posts
msg #38404
Ignore alf44
10/11/2005 3:07:06 PM

...and HERE's the "SHORT" version...

...that is...stocks that have Closed below the Lows of the last 2 days...with 175% increase in Volume above the Average Volume(20)...

---------------------

Fetcher[/* Close below Lows of last 2 days w/175% increase in AvgVol(20) */

set{avgVol_20, Average Volume(20)}
set{VolA, Volume / avgVol_20}
set{VolB, VolA - 1}
set{Volpct_incr, VolB * 100}

Show all stocks where

Close is below Low 2 days ago and
Close is below Low 1 day ago and
Volpct_incr is above 175 and
Average Volume(20) is above 100000 and
Price is above 7

and add column Average Volume(20) {avgVol_20}
and add column Volpct_incr
]



----------------------

Again...simple but VERY effective ! imo


Regards,

alf44




StockFetcher Forums · General Discussion · volume increase<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.